Title : CICS LOCAL DL/I to DBCTL IMSGEN Conversion aid

Submitter : Dougie Lawson
            Consultant Systems Programmer
            IBM UK

Phone : 01256 341061

Release Submitter Details - Y

Text :-

This allows CICS/Local/DL/1 users to assemble their CICS tables and
generate IMS DBCTL stage1 macros.

The following 2 examples and their JCL show how to use the 2 macros
to be found further down the file.

JASMDBD   -  JCL for DBD conversion example
JASMPSB   -  PSB for DBD conversion example
CICSDBD   -  DBD conversion sample
CICSPSB   -  PSB conversion sample
DFHDLDBD  -  DBD convesrion macro
DFHDLPSB  -  PSB conversion macro


JASMDBD sample JCL :-

// EXEC PGM=ASMA90,REGION=4M,PARM='NOOBJECT,DECK'                       00010002
//SYSPRINT DD SYSOUT=*                                                  00020000
//SYSUT1 DD UNIT=SYSDA,SPACE=(CYL,(1,1))                                00030000
//SYSLIB DD DSN=xxx.IMS.MACROS,DISP=SHR                                 00040001
//SYSPUNCH DD SYSOUT=*                                                  00060000
//SYSIN DD DSN=xxx.TEST.CNTL(CICSDBD),DISP=SHR                          00070001


JASMPSB sample JCL :-

// EXEC PGM=ASMA90,REGION=4M,PARM='NOOBJECT,DECK'                       00010002
//SYSPRINT DD SYSOUT=*                                                  00020000
//SYSUT1 DD UNIT=SYSDA,SPACE=(CYL,(1,1))                                00030000
//SYSLIB DD DSN=xxx.IMS.MACROS,DISP=SHR                                 00040002
//SYSPUNCH DD SYSOUT=*                                                  00060000
//SYSIN DD DSN=xxx.TEST.CNTL(CICSPSB),DISP=SHR                          00070002


CICSDBD sample source :-

         DFHDLDBD TYPE=INITIAL,DL1=3.1.0,SUFFIX=DL
         DFHDLDBD TYPE=ENTRY,DBD=XX1,ACCESS=RO
         DFHDLDBD TYPE=ENTRY,DBD=XX2,ACCESS=RD
         DFHDLDBD TYPE=ENTRY,DBD=XX3,ACCESS=UP
         DFHDLDBD TYPE=ENTRY,DBD=XX4,ACCESS=EX
         DFHDLDBD TYPE=ENTRY,DBD=XX5
         DFHDLDBD TYPE=FINAL
         END   DFHIDMD0


CICSPSB sample source :-

         DFHDLPSB TYPE=INITIAL,DL1=3.1.0,SUFFIX=DL                      00010001
         DFHDLPSB TYPE=ENTRY,PSB=XX1                                    00020001
         DFHDLPSB TYPE=ENTRY,PSB=XX2,                                  X00030001
               MXSSASZ=12345,SYSIDNT=WXYZ                               00040001
         DFHDLPSB TYPE=ENTRY,PSB=XX3,                                  X00050001
               MXSSASZ=12345,SYSIDNT=WXYZ,RMTNAME=X3X                   00060001
         DFHDLPSB TYPE=FINAL                                            00070001
         END   DFHIDIR0                                                 00080001


DFHDLDBD Macro :-

         MACRO
&LABEL   DFHDLDBD  &INDEX,         POSITIONAL, FOR DOCUMENTATION ONLY  *
               &TYPE=,             TYPE OF ENTRY                       *
               &DBD=,              DBD NAME                            *
               &DLI=,                                                  *
               &DL1=,                                                  *
               &ACCESS=,           ACCESS LEVEL FOR DATASHARING        *
               &SUFFIX=            MODULE SUFFIX            @E8D0E @L1C
         AIF   ('&TYPE' NE 'ENTRY').NOTENT
         AIF   ('&ACCESS' EQ '').NOACESS
         PUNCH '         DATABASE DBD=&DBD,ACCESS=&ACCESS'
         AGO   .EXIT
.NOACESS ANOP
         PUNCH '         DATABASE DBD=&DBD'
         AGO   .EXIT
.NOTENT  ANOP
         AIF   ('&TYPE' NE 'FINAL').EXIT
         PUNCH '* Please delete the next two lines'
DFHIDMD0 CSECT
.EXIT    ANOP
         MEND


DFHDLPSB Macro :-

         MACRO
&LABEL   DFHDLPSB  &TYPE=,         TYPE OF ENTRY                       *
               &PSB=,              PSB NAME                            *
               &MXSSASZ=,          MAX SSA SIZE(REMOTE PSB)            *
               &RMTNAME=,          PSB NAME ON REMOTE SYS              *
               &SYSIDNT=,          REMOTE SYSTEM NAME                  *
               &DLI=,                                                  *
               &DL1=,                                                  *
               &SUFFIX=            MODULE SUFFIX               @BC5C11H
         AIF   ('&TYPE' NE 'ENTRY').NOTENT
         AIF   ('&SYSIDNT' NE '').REMOTE
         PUNCH '         APPLCTN PSB=&PSB,PGMTYPE=BATCH,SCHDTYP=PARALLE*
               L'
         AGO   .EXIT
.REMOTE  ANOP
         PUNCH '* REMOTE PSB &PSB - No IMS definition generated'
         AGO   .EXIT
.NOTENT  ANOP
         AIF   ('&TYPE' NE 'FINAL').EXIT
         PUNCH '* Please delete the next two lines'
DFHIDIR0 CSECT
.EXIT    ANOP
         MEND


<END>